Quick-and-dirty random encounter mechanic in Godot

Posted: 2025-04-01 | Categories: Programming, Video Games

I’m surprised that I managed to get this done in about 20 minutes last night given that I’ve come back to Godot after nearly 3 years!

Anyways, we’ll be writing a barebones random encounter mechanic here. From my experience with some 90s to mid 2000s JRPGs, I think random encounters generally work as such:

Start a timer of a random duration that counts down to a random encounter
Pause this timer if the player stops moving / is idle
Resume the same timer when the player starts moving again

This is what we shall implement.

Project setup

We’ll have a total of 3 scenes: one for the player, one for the “main” scene, and one that contains the code for the random encounters.

Player scene

I went a bit overkill with the player scene, since I set up animations with this spritesheet and added a sprinting mechanic. You don’t need to do this, but you can if you want.

This is how I have my player scene set up:

Writing player movement isn’t the focus of this article, so I’ll just put the code that handles player movement below.

 1extends CharacterBody2D
 2
 3enum directions {UP, DOWN, LEFT, RIGHT}
 4var current_direction = directions.DOWN
 5var screen_size
 6var is_sprinting
 7@export var speed = 250
 8@onready var animated_sprite = get_node("AnimatedSprite2D")
 9
10func _ready() -> void:
11	screen_size = get_viewport_rect().size
12
13func _process(delta: float) -> void:
14	handle_player_movement(delta)
15
16func handle_player_movement(delta):
17	if Input.is_action_just_pressed("sprint"):
18		speed *= 1.5
19		is_sprinting = true
20	if Input.is_action_just_released("sprint"):
21		speed /= 1.5
22		is_sprinting = false
23
24	# determine direction of movement
25	velocity = Vector2.ZERO
26	if Input.is_action_pressed("move_right"):
27		velocity.x += 1
28		current_direction = directions.RIGHT
29	if Input.is_action_pressed("move_left"):
30		velocity.x -= 1
31		current_direction = directions.LEFT
32	if Input.is_action_pressed("move_up"):
33		velocity.y -= 1
34		current_direction = directions.UP
35	if Input.is_action_pressed("move_down"):
36		velocity.y += 1
37		current_direction = directions.DOWN
38	
39	# normalise movement vector
40	if velocity.length() > 0:
41		velocity = velocity.normalized() * speed
42	
43	# update player position
44	position += velocity * delta
45	position = position.clamp(Vector2.ZERO, screen_size)
46
47	# handle animations
48	if velocity.length() == 0:
49		match current_direction:
50			directions.RIGHT:
51				animated_sprite.flip_h = false
52				animated_sprite.play("idle_left_right")
53			directions.LEFT:
54				animated_sprite.flip_h = true
55				animated_sprite.play("idle_left_right")
56			directions.UP:
57				animated_sprite.play("idle_up")
58			directions.DOWN:
59				animated_sprite.play("idle_down")
60	else:
61		if velocity.x > 0 and velocity.y == 0:
62			animated_sprite.flip_h = false
63			if is_sprinting:
64				animated_sprite.play("sprint_left_right")
65			else:
66				animated_sprite.play("walk_left_right")
67		if velocity.x < 0 and velocity.y == 0:
68			animated_sprite.flip_h = true
69			if is_sprinting:
70				animated_sprite.play("sprint_left_right")
71			else:
72				animated_sprite.play("walk_left_right")
73		if velocity.y > 0 and velocity.x == 0:
74			animated_sprite.play("walk_down")
75		if velocity.y < 0 and velocity.x == 0:
76			animated_sprite.play("walk_up")

If you want this code to work via copy/pasting, then you’ll have to set up the animations for the sprite and the input map yourself.

Also, this code is probably pretty convoluted; I just needed something quick.

Adding signals

We’ll emit a signal whenever the player moves or stops moving. These signals we shall connect in our random encounter script, which we’ll write in just a bit.

First, define two signals.

1signal player_moving
2signal player_stopped

Then, at line 49, add player_stopped.emit() and at line 61, player_moving.emit(). That’s it!

Random encounter scene

There are only two things here: a regular ol’ Node and a timer (which I’ve named to “random_encounter_timer”). You’ll want to attach a script to the node.

Connecting the signals we defined
Firstly, create a “main” scene and add your player and this new random encounter scene in it. Then, select your player and find the signals we defined on the right-hand side.
Double click on each signal, and connect it to the script we created in the random encounter scene.

We’ll add one more signal to our random encounter script, which is the timer’s timeout signal. You can connect that in a similar fashion to the other signals. There should be 3 functions now in that script.

Now comes the actual meat of this article.

Remember what we read about random encounters above:

Start a timer of a random duration that counts down to a random encounter
Pause this timer if the player stops moving / is idle
Resume the same timer when the player starts moving again

Let’s start with the timer. Remember, we don’t want the timer to run if the player is idle, so it makes sense to start it when we get the signal of player movement.

1func _on_player_player_movement():
2    timer_duration = randf.range(0.5, 1.0) * 2
3    random_encounter_timer.start(timer_duration)

There’s no particular reason as to why I’m doing the timer duration that way; I thought it was easier for testing purposes.

We also know that we want to trigger a random encounter when the timer times out.

1func on_random_encounter_timer_timeout():
2    print("Random encounter!")

And, we also want to pause this timer when the player stops moving.

1func _on_player_player_stopped():
2    random_encounter_timer.set_paused(true)

The main issue now is that we’ll be starting a new timer every time the player moves. We want to allow any timer we set to complete first, before we start a new one. So, we’ll check if we currently have a timer going in the background.

1func _on_player_player_movement():
2    # if no timer is running, start a new one.
3    if random_encounter_timer.is_stopped():         
4        timer_duration = randf.range(0.5, 1.0) * 2
5        random_encounter_timer.start(timer_duration)
6
7    # if we have a paused timer, resume it.
8    if random_encounter_timer.is_paushed():
9        random_encounter_timer.set_paused(false)

That’s it!

Here’s all the code:

 1extends Node
 2
 3@onready var random_encounter_timer = get_node("random_encounter_timer")
 4
 5var timer_duration = 0
 6
 7func _on_random_encounter_timer_timeout() -> void:
 8	print("Random encounter!")
 9
10func _on_player_player_moving() -> void:
11	if random_encounter_timer.is_stopped():
12		timer_duration = randf_range(0.5, 1.0) * 2
13		random_encounter_timer.start(timer_duration)
14	if random_encounter_timer.is_paused():
15		random_encounter_timer.set_paused(false)
16
17func _on_player_player_stopped() -> void:
18	random_encounter_timer.set_paused(true)

I’ll put a clip of this below; you should be able to see it working in the console.

I don’t write guides very often, so let me know if I can explain anything here better!